CheckPoint [Padėkite]

[SomTrike]

Sveiki visi gta-online.lt lankytojai. Turiu bėdą. Susikūriau PICKUP ant kurio užlipus atsiranda checkpoint, tada užlipus (pėščiomis) ant atsiradusio checkpoint turi atsirasti kitas, tada kitas ir t.t., bet taip nėra. Užlipu ant checkpoint ir jis dingsta o kitas nebeatsiranda. Mano kodas:

Čia užlipus ant PICKUP išmeta GUI lentelę ir jeigu su ja sutinku atsiranda pirmasis checkpoint :

if(dialogid == 1598)
 {
 if(response)
 {
 pdb1[playerid] = SetPlayerCheckpoint(playerid, -2106.1753,-211.3944,35.3203, 3.0);
 InfoBoxForPlayer(playerid, "~g~ Sekmes!");
 }
 return 1;
 }

Čia kiti kodai:

public OnPlayerEnterCheckpoint(playerid)
{
if(pdb1[playerid] == 1)
{
pdb2[playerid] = SetPlayerCheckpoint(playerid, -2106.0945,-205.6722,35.3203, 3.0);
pdb1[playerid]=-1;
}
else if(pdb2[playerid] == 1)
{
vm3[playerid] = SetPlayerCheckpoint(playerid, -2106.5005,-196.6685,35.6548, 3.0);
vm2[playerid]=-1;
}
else if(pdb3[playerid] == 1)
{
pdb4[playerid] = SetPlayerCheckpoint(playerid, -2105.9924,-190.6906,35.3203, 3.0);
pdb3[playerid]=-1;
}
else if(pdb4[playerid] == 1)
{
pdb5[playerid] = SetPlayerCheckpoint(playerid, -2105.6802,-185.2033,35.3203, 3.0);
pdb4[playerid]=-1;
}
else if(pdb5[playerid] == 1)
{
pdb6[playerid] = SetPlayerCheckpoint(playerid, -2105.7314,-178.1248,35.3203, 3.0);
pdb5[playerid]=-1;
}
else if(pdb6[playerid] == 1)
{
pdb7[playerid] = SetPlayerCheckpoint(playerid, -2105.9448,-171.8022,35.3203, 3.0);
pdb6[playerid]=-1;
}
else if(pdb7[playerid] == 1)
{
pdb8[playerid] = SetPlayerCheckpoint(playerid, -2106.1306,-165.1817,35.3203, 3.0);
pdb7[playerid]=-1;
}
else if(pdb8[playerid] == 1)
{
pdb9[playerid] = SetPlayerCheckpoint(playerid, -2099.2900,-163.7819,35.3203, 3.0);
pdb8[playerid]=-1;
}
else if(pdb9[playerid] == 1)
{
pdb10[playerid] = SetPlayerCheckpoint(playerid, -2099.2395,-213.6884,35.3203, 3.0);
pdb9[playerid]=-1;
}
else if(pdb10[playerid] == 1)
{
DisablePlayerCheckpoint(playerid);
GameTextForPlayer(playerid,"Begimo uzduotis ~g~Baigta",2000,5);
pdb10[playerid]=-1;
playerDB[playerid][pdamasina]=1;
return 1;
}

P.S. Gal viršijau CP limitą ir man jų nerodo?

[laimis321]

O tu nori daryti kaška su Vairavimo mokykla ?

[SomTrike]

Noriu daryti Policijos Mokykla ir čia viena iš rungčių, tai bėgimas kliūtimis per CP.

[renaldasj]

tu keistai padarėi. Susikrk glob. kintamaji new bool:VAIKSTO[MAX_PLAYERS];

new VAIKSTOCP[MAX_PLAYERS];

tada pickupe rašai VAIKSTO[playerid]=true; // Vaikšto true.

ir tada pirma cp

VAIKSTOCP[playerid]=1;

CreateCheckpoin t.t

OnPlayerEnterCheckpoint

if(VAIKSTO[playerid]==true)

{

if(VAIKSTOCP[playerid]==1)

{

VAIKSTOCP[playerid]=2;

SetPlayerCheckpoint.t.t

}

else if(VAIKSTOCP[playerid]==2)

{

VAIKSTOCP[playerid]=3;

}

}

kai bus paskutinis CP parašyk šita:

VAIKSTO[playerid]=false;

AŠ PER TELEFA.

[SomTrike]

Man gerai kaip yra, tik kame yra problema?

[bebras]

Funkcija "SetPlayerCheckpoint" nieko negražina. Todėl "kintamasis = SetPlayerCheckpoint();" kintamasis lieka 0.

[SomTrike]

Funkcija "SetPlayerCheckpoint" nieko negražina. Todėl "kintamasis = SetPlayerCheckpoint();" kintamasis lieka 0.

Gali biški aiškiau?

[bebras]

Gali biški aiškiau?

pdb1[playerid] = SetPlayerCheckpoint(playerid, -2106.1753,-211.3944,35.3203, 3.0);
printf("Tavo kintamasis: %d", pdb1[playerid]);

Bus parašyta "Tavo kintamasis: 0"

[SomTrike]

Tai ka siūlai man daryti?

[renaldasj]

aš nesuprantu, kam kurti atskira kintamaji.... new pdb1[MAX_PLAYERS] ; ir tt? jeigu galima lengviau?

[ES.^]

#include <a_samp>
new pCP[MAX_PLAYERS];

public OnPlayerConnect(playerid)
{
   pCP[playerid] = -1;
   return 1;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
   if(dialogid == 1598)
   {
       if(response)
       {
           pCP[playerid] = 0;
           SetPlayerCheckpoint(playerid, -2106.1753, -211.3944, 35.3203, 3.0);
           InfoBoxForPlayer(playerid, "~g~ Sekmes!");
       }
       return 1;
   }
   return 1;
}

public OnPlayerEnterCheckpoint(playerid)
{
   if(pCP[playerid] != -1)
   {
       pCP[playerid] ++;
       switch(pCP[playerid])
       {
           case 1: SetPlayerCheckpoint(playerid, -2106.0945, -205.6722, 35.3203, 3.0);
           case 2: SetPlayerCheckpoint(playerid, -2106.5005, -196.6685, 35.6548, 3.0);
           case 3: SetPlayerCheckpoint(playerid, -2105.9924, -190.6906, 35.3203, 3.0);
           case 4: SetPlayerCheckpoint(playerid, -2105.6802, -185.2033, 35.3203, 3.0);
           case 5: SetPlayerCheckpoint(playerid, -2105.7314, -178.1248, 35.3203, 3.0);
           case 6: SetPlayerCheckpoint(playerid, -2105.9448, -171.8022, 35.3203, 3.0);
           case 7: SetPlayerCheckpoint(playerid, -2106.1306, -165.1817, 35.3203, 3.0);
           case 8: SetPlayerCheckpoint(playerid, -2099.2900, -163.7819, 35.3203, 3.0);
           case 9: SetPlayerCheckpoint(playerid, -2099.2395, -213.6884, 35.3203, 3.0);
           case 10:
           {
               pCP[playerid] = -1;
               playerDB[playerid][pdamasina] = 1;
               DisablePlayerCheckpoint(playerid);
               GameTextForPlayer(playerid, "Begimo uzduotis ~g~Baigta", 2000, 5);
           }
       }
   }
   return 1;
}

[SomTrike]

ES dėkoju už pagalba