Reikia komandos (anti-cheat)

[Sofoklis]

Sveiki, yra tokia problemėlė, evente padalinu kulkas žaidėjam ir iš jų 1-3 gauna kick nuo anti - cheat už gunus, kaip neištrynus anti - cheat padaryt, kad davus kulkas nekickintu?

[Barz]

Visų pirma sužinok kodėl kickina, paskui galima spręst problema, jei kažką dabar darysim nežinodami kokia kick priežastis tai nieko ir nepadarysim. Galbūt duodi draudžiamus ginklus ar etc

[Sofoklis]

23 minutes prieš, Barz parašė:

Visų pirma sužinok kodėl kickina, paskui galima spręst problema, jei kažką dabar darysim nežinodami kokia kick priežastis tai nieko ir nepadarysim. Galbūt duodi draudžiamus ginklus ar etc

Nesvarbu kokius gunus beduočiau, vistiek iškickina kažkiek žmonių (kartais nieko(retai)) 

[TomyG]

1 minute prieš, Juodas Angelas parašė:

Nesvarbu kokius gunus beduočiau, vistiek iškickina kažkiek žmonių (kartais nieko(retai)) 

tai rodyk kodą

[Sofoklis]

Kulku padalinimo: 

CMD:egun( playerid, params[ ] )
{
    new
        Float: range,
        weaponid,
        ammo
    ;
    if( sscanf( params, "fdd", range, weaponid, ammo ) ) return SendClientMessage( playerid, -1, "Naudojimas: /egun (atstumas) (gunid) (kulkusk)" );
    switch( weaponid )
    {
        case 0 .. 18, 22 .. 46:
        {
            new
                Float: x,
                Float: y,
                Float: z
            ;
            GetPlayerPos( playerid, x, y, z );
            for( new i = 0; i < MAX_PLAYERS; i++ )
            {
                if( !IsPlayerConnected( i ) ) continue;
                if( IsPlayerInRangeOfPoint( i, range, x, y, z ) ) GivePlayerWeapon( i, weaponid, ammo );
            }
        }
        default: SendClientMessage( playerid, -1, "Blogas ginklu id" );
    }
    return 1;
}

Anti Cheat  (cj tas)

forward ServerWeapon(playerid, weaponid, ammo);
public ServerWeapon(playerid, weaponid, ammo)
{
    KillTimer(WeaponTimer[playerid]);
    WeaponTimer[playerid]=SetTimerEx("AntiGun",2000,false,"i",playerid);
    AntiCheat[playerid][CanCheck]=false;
    if(weaponid >= 1 && weaponid <= 9)
    {
        AntiCheat[playerid][Melee] = weaponid;
        GivePlayerWeapon(playerid, weaponid, ammo);
        return 1;
    }
    if( weaponid >= 16 && weaponid <= 18 || weaponid == 39 ) // Checking Thrown
    {
        if(AntiCheat[playerid][ThrownAmmo]>0)
        {
            if(AntiCheat[playerid][Thrown] == weaponid)
                AntiCheat[playerid][ThrownAmmo]+= ammo;
            else AntiCheat[playerid][ThrownAmmo]= ammo;
        }
        else
        {
            AntiCheat[playerid][ThrownAmmo]= ammo;
        }
        AntiCheat[playerid][Thrown] = weaponid;
        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Thrown], AntiCheat[playerid][ThrownAmmo]);
        return 1;
    }
    if( weaponid >= 22 && weaponid <= 24 ) // Checking Pistols
    {
        if(AntiCheat[playerid][PistolsAmmo]>0)
        {
            if(AntiCheat[playerid][Pistols] == weaponid)
                AntiCheat[playerid][PistolsAmmo]+= ammo;
            else
                AntiCheat[playerid][PistolsAmmo]= ammo;
        }
        else
        {
            AntiCheat[playerid][PistolsAmmo]=ammo;
        }
        AntiCheat[playerid][Pistols] = weaponid;
        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Pistols], AntiCheat[playerid][PistolsAmmo]);
        return 1;
    }
    if( weaponid >= 25 && weaponid <= 27 ) // Checking Shotguns
    {

        if(AntiCheat[playerid][ShotgunsAmmo]>0)
        {
            if(AntiCheat[playerid][Shotguns] == weaponid)
                AntiCheat[playerid][ShotgunsAmmo]+= ammo;
            else
                AntiCheat[playerid][ShotgunsAmmo]=ammo;
        }
        else
            AntiCheat[playerid][ShotgunsAmmo]=ammo;

        AntiCheat[playerid][Shotguns] = weaponid;
        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Shotguns], AntiCheat[playerid][ShotgunsAmmo]);
        return 1;
    }
    if( weaponid == 28 || weaponid == 29 || weaponid == 32 ) // Checking Sub Machine Guns
    {

        if(AntiCheat[playerid][SubMachineAmmo]>0)
        {
            if(AntiCheat[playerid][SubMachine] == weaponid)
                AntiCheat[playerid][SubMachineAmmo]+= ammo;
            else
                AntiCheat[playerid][SubMachineAmmo]=ammo;
        }
        else
            AntiCheat[playerid][SubMachineAmmo]=ammo;

        AntiCheat[playerid][SubMachine] = weaponid;

        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][SubMachine], AntiCheat[playerid][SubMachineAmmo]);
        return 1;
    }

    if( weaponid == 30 || weaponid == 31 ) // Checking Assault
    {
        if(AntiCheat[playerid][AssaultAmmo]>0)
        {
            if(AntiCheat[playerid][Assault] == weaponid)
                AntiCheat[playerid][AssaultAmmo]+= ammo;
            else
                AntiCheat[playerid][AssaultAmmo]= ammo;
        }
        else
            AntiCheat[playerid][AssaultAmmo]=ammo;

        AntiCheat[playerid][Assault] = weaponid;

        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Assault], AntiCheat[playerid][AssaultAmmo]);
        return 1;
    }

    if( weaponid == 33 || weaponid == 34 ) // Checking Rifles
    {

        if(AntiCheat[playerid][RiflesAmmo]>0)
        {
            if(AntiCheat[playerid][Rifles] == weaponid)
                AntiCheat[playerid][RiflesAmmo]+= ammo;
            else
                AntiCheat[playerid][RiflesAmmo]= ammo;
        }
        else
            AntiCheat[playerid][RiflesAmmo]=ammo;

        AntiCheat[playerid][Rifles] = weaponid;

        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Rifles], AntiCheat[playerid][RiflesAmmo]);
        return 1;
    }
    if( weaponid >= 35 && weaponid <= 38 ) // Checking Heavy
    {
        if(AntiCheat[playerid][HeavyAmmo]>0)
        {
            if(AntiCheat[playerid][Heavy] == weaponid)
                AntiCheat[playerid][HeavyAmmo]+= ammo;
            else
                AntiCheat[playerid][HeavyAmmo]=ammo;
        }
        else
            AntiCheat[playerid][HeavyAmmo]=ammo;

        AntiCheat[playerid][Heavy] = weaponid;

        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Heavy], AntiCheat[playerid][HeavyAmmo]);
        return 1;
    }
    if( weaponid >= 41 && weaponid <= 43)
    {
        if(AntiCheat[playerid][HandheldAmmo]>0)
        {
            if(AntiCheat[playerid][Handheld] == weaponid)
                AntiCheat[playerid][HandheldAmmo]+= ammo;
            else
                AntiCheat[playerid][HandheldAmmo] = ammo;
        }
        else
            AntiCheat[playerid][HandheldAmmo]=ammo;

        AntiCheat[playerid][Handheld] = weaponid;

        SetPlayerAmmo(playerid, weaponid, 0);
        GivePlayerWeapon(playerid, AntiCheat[playerid][Handheld], AntiCheat[playerid][HandheldAmmo]);
        return 1;
    }
    return 1;
}

 

[Riccardo]

Komandoje /egun

pakeisk iš  :

GivePlayerWeapon( i, weaponid, ammo );

į  :

ServerWeapon( i, weaponid, ammo );

 

[Sofoklis]

prieš 14 valandas(-ų), L'M parašė:

Komandoje /egun

pakeisk iš  :

GivePlayerWeapon( i, weaponid, ammo );

į  :

ServerWeapon( i, weaponid, ammo );

 

Dėkui