[Pamoka]Verslų sistema

bebras · Rugsėjo 24, 2013

Sveiki, tai bus viena iš mano didžiausių pamokų(bent aš taip manau). Kaip jau tikiuosi supratot tai bus verslų sistema. Kadangi nemėgstu įžangų, einam prie reikalo.

Ko mums reikės?

BlueG MySQL plugin + include R33
ZCMD include
sscanf plugin + include
Veikiančios duomenų bazės
Svarbiausia! Noro.

Okei, pradėsim nuo pagrindinių dalyku, kintamieji,numeracijos,define:

#define MAX_VERSLAI 500 // Maksimalus verslų skaičius, keiskit pagal poreikius
#define VERSLU_SPALVA 0x00FF00FF //Tai nėra butinybė, tai tik spalva kurią naudosiu visoms žinutėms bei label.
#define DIALOG_ACCEPT_VERSLA 5154 // Tai GUI lentelės ID(dialogid). Pas jus neturėtų būti lentelės su tokiu ID, jei yra - pakeiskit šį.
 
enum v_info {
	ORM:Ormid,
	Id,
	Savininkas[MAX_PLAYER_NAME],
	Pavadinimas[101],
	Float:EnX,
	Float:EnY,
	Float:EnZ,
	InterjeroNr,
	Kaina,
	PelnasH,
	Pelnas,
	Locked,
	Text3D:Label
};

new Verslai[MAX_VERSLAI][v_info]; // Masyvas kuriame laikysime informaciją veikimo metu


enum interior_info {
	Float:x,
	Float:y,
	Float:z,
	Int
};


// Tai antrasis masyvas skirtas interjerams
// Pirmieji trys skaičiai yra iėjimo koordinatės, o ketvirtasis tikrasis interjero ID
// Galite jų pridėt neribotą skaičių
static const Interiors[][interior_info] = {
	{-25.8844,-185.8689,1003.5499,17}, // 24/7 parduotvės interjeras
	{2233.8032,1712.2303,1011.7632,1} // Caligula kazino interjeras
};

new Db; // Kintamasis kuriame bus laikomas prisijungimo prie DB numeris.

Jeigu nebuvo aiški dalis apie interjerus ir jų masyvą, palaukite vėlesnio laiko, viskas paaiškės tada.

Pirmiausia prisijunkime prie duomenų bazės:

Db = mysql_connect("localhost","root","testas","");

Norėtųsi galėti užkrauti tuos verslus ar ne? Tai ir padarysime:

stock KrautiVerslus()
	return mysql_tquery(Db,"SELECT * FROM verslai","OnVerslaiLoad",""); //Išsiunčiame užklausą į duomenų bazę, ir nurodome kad grižus užklausa iškviestų funkcija "OnVerslaiLoad"

forward OnVerslaiLoad();
public OnVerslaiLoad()
{
	new str[128];
	for(new i; i < cache_get_row_count(); i++) // cache_get_row_count reiškia eilučių skaičių
	{
		Verslai[i][Ormid] = orm_create("verslai"); // Sukuriame orm ryšį su verslų lentele
		orm_addvar_int(Verslai[i][Ormid],Verslai[i][Id],"Id"); //Pridedame stulpelį "id" prie ryšio
		orm_setkey(Verslai[i][Ormid],"Id"); // Nustatome kad eilutės duomenų bazėje bus skiriamos pagal šį sulpelį
		orm_addvar_string(Verslai[i][Ormid],Verslai[i][Savininkas],MAX_PLAYER_NAME,"Savininkas"); // Pridedame stulpelį "savininkas" prie ryšio
		orm_addvar_string(Verslai[i][Ormid],Verslai[i][Pavadinimas],101,"Pavadinimas");
		orm_addvar_float(Verslai[i][Ormid],Verslai[i][EnX],"EnX");
		orm_addvar_float(Verslai[i][Ormid],Verslai[i][EnY],"EnY");
		orm_addvar_float(Verslai[i][Ormid],Verslai[i][EnZ],"EnZ");
		orm_addvar_int(Verslai[i][Ormid],Verslai[i][InterjeroNr],"InterjeroNr");
		orm_addvar_int(Verslai[i][Ormid],Verslai[i][Kaina],"Kaina");
		orm_addvar_int(Verslai[i][Ormid],Verslai[i][PelnasH],"PelnasH");
		orm_addvar_int(Verslai[i][Ormid],Verslai[i][Pelnas],"Pelnas");
		orm_addvar_int(Verslai[i][Ormid],Verslai[i][Locked],"Locked");
		//Eilutės prie šią, neturi komentarų kadangi veiksmas kartojasi. Dvi eilutės pirmosios yra pakomentuotos
		 
		orm_apply_cache(Verslai[i][Ormid],i); // Tai užkraus duomenis į kintamuosius susietus višuje.

		// Krovimas baigtas, dabar galime parodyti kažką serveryje
		if(isnull(Verslai[i][Savininkas])) format(str,sizeof(str),"Verslas parduodamas\nKaina:%d\nValandos pelnas:%d",
			Verslai[i][Kaina],Verslai[i][PelnasH]);

		else format(str,sizeof(str),"%s\nSavininkas:%s",Verslai[i][Pavadinimas],Verslai[i][Savininkas]);
		//Kodas viršuje nustatys ar verslas turi savininka ar ne, atitinkamai pagal tai suformatuos žinutę teksto etiketei(3DTextLabel)
		 
		Verslai[i][Label] = Create3DTextLabel(str,VERSLU_SPALVA,Verslai[i][EnX],Verslai[i][EnY],Verslai[i][EnZ],25.0,0,1);//Sukuriame minėta etiketę. Parametras po Z koordinatės reiškia atsumą kuriuo bus matoma etiketė
	}
	return 1;
}

Atskirai pakomentuosiu tik funkcijos "mysql_tquery" pirmąjį parametrą. Tai yra skaičius kurį gražina "mysql_connect" funkcija.

Šioje sistemoje į verslus bus galima įeiti būnant netoli jų ir paspaudžiant mygtuką "ENTER"(galite keistis, visi mygtukų pavadinimai):

public OnPlayerKeyStateChange(playerid,newkeys,oldkeys)
{
	if((newkeys & KEY_SECONDARY_ATTACK) && !(oldkeys & KEY_SECONDARY_ATTACK)) // Patikriname ar žaidėjas paspaudė "KEY_SECONDARY_ATTACK", tai yra ENTER mygtukas. Galite keisti
	{
		if(IsPlayerInAnyVehicle(playerid)) return 0; // Jeigu žaidėjas transporto priemonėje, jam įeiti neleisime, todėl net neverta tikrinti prie kokio jis verslo.
		for(new i; i < MAX_VERSLAI; i++)
		{
			if(Verslai[i][Id] == 0) continue; // Jeigu tai tuščia verslo masyvo dalis, praleidžiame kodą apačioje ,grįžtame prie ciklo.
			if(IsPlayerInRangeOfPoint(playerid,5.0,Verslai[i][EnX],Verslai[i][EnY],Verslai[i][EnZ])) // Jeigu žaidėjas yra prie verslo įėjimo
			{
				if(Verslai[i][Locked] == 1) //Jei užrakinta
				{
					SendClientMessage(playerid,VERSLU_SPALVA,"Verslas užrakintas,pabandykite vėliau");
					return 0;
				}

				// Dabar ir naudosime masyvą "Interiors". Plačiau bus po kodu -> Žiūrėti pamokoje.
				SetPlayerInterior(playerid,Interiors[Verslai[i][InterjeroNr]][Int]); //Nustatome žaidėjo interjerą
				SetPlayerPos(playerid,Interiors[Verslai[i][InterjeroNr]][x],Interiors[Verslai[i][InterjeroNr]][y],Interiors[Verslai[i][InterjeroNr]][z]);
				SetPlayerVirtualWorld(playerid,Verslai[i][Id]); // Nustatome virtualuųjį pasaulį į unikalų tam verslui skaičių
				return 0;
			}
			if(GetPlayerVirtualWorld(playerid) == Verslai[i][Id]) // Jeigu žaidėjo virtualusis pasaulis lygus verslo ID. (Porą eilučių į viršų tai nustatome)
			{
				if(IsPlayerInRangeOfPoint(playerid,5.0,Interiors[Verslai[i][InterjeroNr]][x],Interiors[Verslai[i][InterjeroNr]][y],Interiors[Verslai[i][InterjeroNr]][z])
					&& GetPlayerVirtualWorld(playerid) == Verslai[i][Id] 
					&& GetPlayerInterior(playerid) == Interiors[Verslai[i][InterjeroNr]][Int]) // Jeigu žaidėjas yra prie išėjimo. Tai nusprendžiam pagal jo buvimo vietą, virtualų pasaulį ir interjerą.
				{
					if(Verslai[i][Locked] == 1) //Jei užrakinta
					{
						SendClientMessage(playerid,VERSLU_SPALVA,"Verslas užrakintas");
						return 0;
					}
					// Jeigu iki čia atėjome, reiškia verslas atrakintas ir galima įeiti.
					SetPlayerInterior(playerid,0);
					SetPlayerPos(playerid,Verslai[i][EnX],Verslai[i][EnY],Verslai[i][EnZ]);
					SetPlayerVirtualWorld(playerid,0);
					return 0;
				}
			}
		}
	}
	return 1;
}

Taigi dėl masyvo "Interiors". Skaičius kurį saugome verslų masyve ties "InterjeroNr" yra "interiors" masyvo eilutės numeris. Tai reiškia, kad jeigu "InterjeroNr" bus 0, tai informaciją naudosime iš "Interiors[0]". Paprasta ir patogu.

Pagrindas jau yra, matysime verslų etiketes ir galėsime įeiti/išeiti iš jų. Bet mums to juk negana(godumas - žmogiškas bruožas)!
Ko gero reikalingiausias dalykas kurį norėsime padaryti, tai bus parduoti verslą kitam žaidėjui, toliau bus komandą parašyta su ZCMD, galite naudoti ir kitą tipą komandų.

Pirmiausia noriu aptarti ne native[/url]funkcija kurios bus naudojamos komandose(nepastebėkit kad labai prasti pavadinimai funkcijų):


//Funkcija tikrins ar žaidėjas yra prie verslo įėjimo, ir jeigu jis prie įėjimo gražins verslo indeksą.
stock IsPlayerInRangeOfVerslas(playerid,Float:distance=5.0) // Antras parametras nebūtinas, jei jo nebus vietoj jo naudosime skaičių 5.0
{
	for(new i; i < MAX_VERSLAI; i++)
	{
		if(Verslai[i][Id] == 0) continue;
		if(IsPlayerInRangeOfPoint(playerid,distance,Verslai[i][EnX],Verslai[i][EnY],Verslai[i][EnZ])) return i; // Jeigu žaidėjas yra nurodytu atstumu prie verslo įėjimo gražinsime masyvo indeksą
	}
	return -1; // Jeigu žaidėjas nėra prie jokio įėjimo gražiname -1, kas yra netinkamas masyvo indeksas.
}

// Funkcija patikrins ar žaidėjas yra verslo savininkas.
// Atkreipkite dėmesį jog duodame ne verslo unikalų Id, o verslo masyvo indeksą.
stock VersloSavininkas(playerid,vid)
{
	new name[MAX_PLAYER_NAME];
	GetPlayerName(playerid,name,sizeof(name));
	if(!isnull(Verslai[vid][Savininkas]) && !strcmp(Verslai[vid][Savininkas],name)) return true; // Jeigu masyvo dalis "savininkas" ne tuščias ir sutampa su žaidėjo vardu, reiškia jis savininkas
	return false;
}

Iš funkcijų noriu paminėti dėl tikrinimo "isnull" tai yra labai svarbu, kadangi jeigu vienas string yra tuščias, funkcija "strcmp" teigs jo jie vienodi.

Ir pagaliau priėjome prie pardavimo komandos:

CMD:parduotiversla(playerid,params[])
{
	new verslas = IsPlayerInRangeOfVerslas(playerid,5.0),pid,kaina,str[70],name[MAX_PLAYER_NAME];
	if(verslas == -1) return SendClientMessage(playerid,VERSLU_SPALVA,"Turite būti prie verslo įėjimo");
	if(!VersloSavininkas(playerid,verslas)) return SendClientMessage(playerid,VERSLU_SPALVA,"Tai ne jūsų verslas!");
	if(sscanf(params,"u",pid,kaina)) return SendClientMessage(playerid,VERSLU_SPALVA,"Naudojimas /parduotiversla [ZaidejoID/dalis vardo] [Kaina]");
	if(!IsPlayerConnected(pid)) return SendClientMessage(playerid,VERSLU_SPALVA,"Tokio žaidejo nėra");
	if(kaina < 0) return SendClientMessage(playerid,VERSLU_SPALVA,"Kaina neigiama buti negali!");
	
	format(str,sizeof(str),"%s jums siulo pirkti jo verlsa uz %d(Galioja 30sec)",name,kaina);
	ShowPlayerDialog(playerid,DIALOG_ACCEPT_VERSLA,DIALOG_STYLE_MSGBOX,"Verslo pirkimas",str,"Pirkti","Atsisakyti");
	SetPVarInt(pid,"KasSiuloVersla",playerid);
	SetPVarInt(pid,"VersloIndeksas",verslas);
	SetPVarInt(pid,"VersloKaina",kaina);
	return 1;
}

public OnDialogResponse(playerid,dialogid,response,listitem,inputtext[])
{
	if(dialogid == DIALOG_ACCEPT_VERSLA && response) // Jeigu tai lentelė kurią parodėme komandoje IR paspaudė pirmąjį mygtuką (Pirkti)
	{
		if(GetPVarInt(playerid,"VersloKaina") < GetPlayerMoney(playerid)) return SendClientMessage(playerid,VERSLU_SPALVA,"Jums neužtenka pinigų"); // Jeigu žaidėjui neužtenka pinigų
		// Jeigu iki čia atėjom, reiškia pinigų užtenka.
		new name[MAX_PLAYER_NAME],index = GetPVarInt(playerid,"VersloIndeksas"),str[128];
		GetPlayerName(playerid,name,sizeof(name));
		format(Verslai[index][Savininkas],24,name); // Perrašome savininko vardą
		// Kolkokas tinkamas savininkas tik kintamuosiuose, atnaujinkime jį ir 3D teksto etiketėje.
		format(str,sizeof(str),"%s\nSavininkas:%s",Verslai[index][Pavadinimas],Verslai[index][Savininkas]);
		Update3DTextLabelText(Verslai[index][Label],VERSLU_SPALVA,str);

		// Na galima nusiųsti pardavėjui žinutę kad verslas parduotas.
		format(str,sizeof(str),"%s nupirko jūsų verslą uz %d",GetPVarInt(playerid,"KasSiuloVersla"),GetPVarInt(playerid,"VersloKaina"));
		SendClientMessage(GetPVarInt(playerid,"KasSiuloVersla"),VERSLU_SPALVA,str);

		//Ištriname žaidėjo kintamuosius, nes jie mums nebereikalingi
		DeletePVar(playerid,"KasSiuloVersla");
		DeletePVar(playerid,"VersloIndeksas");
		DeletePVar(playerid,"VersloKaina");
		return 1;
	}
	return 0;
}

Dabar, kodėl pasirinkau "PVar"? Aiškinu nes ne kartą mane matėte reiškiantį neigiamą nuomonę apie juos. Atsakymas paprastas, jie bus nedažnai naudojami, juk ne visada žaidėjai pardavinės verslus, t.y. neištisai.

Žinoma bus sunku parduoti verslą, jeigu jo niekas negalės nusipirkti. Tam komanda:

CMD:pirktiversla(playerid,params[])
{
	new verslas = IsPlayerInRangeOfVerslas(playerid,5.0);
	if(verslas == -1) return SendClientMessage(playerid, VERSLU_SPALVA, "Jūs turite būti prie verslo įėjimo!");
	if(!isnull(Verslai[verslas][Savininkas])) 	return SendClientMessage(playerid, VERSLU_SPALVA, "Šis verslas jau turi savininką!");
	if(GetPlayerMoney(playerid) < Verslai[verslas][Kaina]) return SendClientMessage(playerid, VERSLU_SPALVA, "Jums neužtenka pinigų.");

	// Atiimam pinigus.
	GivePlayerMoney(playerid,Verslai[verslas][Kaina]);
	// Gauname žaidėjo vardą ir padarome jį savininku.
	new name[MAX_PLAYER_NAME];
	GetPlayerName(playerid, name, sizeof(name));
	format(Verslai[verslas][Savininkas], MAX_PLAYER_NAME,"%s",name);

	// Atnaujiname teksto etiketę jog būtų rodomas tinkamas savininkas.
	new str[130];
	format(str,sizeof(str),"%s\n%s",Verslai[verslas][Pavadinimas],Verslai[verslas][Savininkas]);
	Update3DTextLabelText(Verslai[verslas][Label], VERSLU_SPALVA,str);

	// Atnaujiname savininką duomenų bazėje.
	orm_update(Verslai[verslas][Ormid]);

	SendClientMessage(playerid, VERSLU_SPALVA, "Sveikiname nusipirkus verslą!");
	return 1; 
}

Toliau komanda skirtą užrakinti arba atrakinti verslą. To kas buvo pakomentuota prieš tai, nekomentuosiu:

CMD:rakintiversla(playerid)
{
	new verslas = IsPlayerInRangeOfVerslas(playerid,5.0);
	if(verslas == -1) return SendClientMessage(playerid,VERSLU_SPALVA,"Turite būti prie verslo įėjimo");
	if(!VersloSavininkas(playerid,verslas)) return SendClientMessage(playerid,VERSLU_SPALVA,"Tai ne jūsų verslas!");
	if(Verslai[verslas][Locked] == 0) // Jei atrakinta
	{
		RakintiVersla(verslas,true);
		SendClientMessage(playerid,VERSLU_SPALVA,"Verslas uzrakintas");
		return 1;
	}
	if(Verslai[verslas][Locked] == 1) //Jei užrakinta
	{
		RakintiVersla(verslas,false);
		SendClientMessage(playerid,VERSLU_SPALVA,"Verslas atrakintas");
		return 1;
	}
	return 1;
}

Komandoje jokio stebuklo nėra. Funkcija "RakintiVersla"

stock RakintiVersla(versloid,bool:status)
{
	Verslai[versloid][Locked] = status;
	orm_update(Verslai[versloid][Ormid]); //Atnaujiname informaciją duomenų bazėje
	return 1;
}

Tikriausia nesupratote "(status) ? (1):(0)" dalies, tai vadinama "triadic operator" ir tai tėra labai supaprastintas(gal ne iš pirmo žvilgsnio) "if" sakinys. Kadangi tai nelabai susiję su verslais, tai nelabai ir aiškinsiu. Tik pasakysiu kad jis naudojamas taip "(sąlyga) ? (Kas bus jei sąlyga true):(kas bus kitais atvejais)"

Kaip turbūt pastebėjote mūsų verslai turi pavadinimą, nesikeičiantis pavadinimas būtų nuobodus, todėl jį leisime keisti:

CMD:keistipavadinima(playerid,params[])
{
	new verslas = IsPlayerInRangeOfVerslas(playerid,5.0),str[128];
	if(verslas == -1) return SendClientMessage(playerid,VERSLU_SPALVA,"Turite būti prie verslo įėjimo");
	if(!VersloSavininkas(playerid,verslas)) return SendClientMessage(playerid,VERSLU_SPALVA,"Tai ne jūsų verslas!");
	if(isnull(params)) SendClientMessage(playerid,VERSLU_SPALVA,"Naudojimas /keistipavadinima [Naujas pavadinimas]");
	if(strlen(params) > 100) return SendClientMessage(playerid, VERSLU_SPALVA, "Pavadinimas per ilgas, daugiausiai gali būti 100 simbolių!");

	strdel(Verslai[verslas][Pavadinimas],0,101); //Ištriname senąjį pavadinimą
	strins(Verslai[verslas][Pavadinimas],params,0,101); // Įrašome naują pavadinimą

	format(str,sizeof(str),"%s\nSavininkas:%s",Verslai[verslas][Pavadinimas],Verslai[verslas][Savininkas]);
	Update3DTextLabelText(Verslai[verslas][Label],VERSLU_SPALVA,str); //Atnaujiname teksto etiktę(3DTextLabel)

	orm_update(Verslai[verslas][Ormid]);//Atnaujiname duomenis duomenų bazėje.
	return 1;
}

Dar viena labai mėgstama ir naudinga komanda, tai verslų pridėjimas žaidimo metu, vienas dalykas ką apie ją pasakysiu, tai kad nėra tikrinimo ar žaidėjas administratorius ko jūs tikriausia norėsite, teks pasidaryti jį patiems:

CMD:pridetiversla(playerid,params[])
{
	new interjeras,kaina,pelnas,Float:pos[3],query[150],i = GetFreeVersloIndex(),str[100]; //Ką daro funkciją "GetFreeVersloIndex" žiūrėkite žemiau
	if(sscanf(params,"ddd",interjeras,kaina,pelnas)) return SendClientMessage(playerid,VERSLU_SPALVA,"Naudojimas /pridetiversla [InterjeroNr] [Kaina] [Valandos pelnas]");
	if(interjeras > sizeof(Interiors) || interjeras < 0) return SendClientMessage(playerid,VERSLU_SPALVA,"Tokio interjero nera!"); // Jeigu masyve interjero su nurodytu numeriu nėra
	GetPlayerPos(playerid,pos[0],pos[1],pos[2]);
	Verslai[i][EnX] = pos[0];
	Verslai[i][EnY] = pos[1];
	Verslai[i][EnZ] = pos[2];
	Verslai[i][InterjeroNr] = interjeras;
	Verslai[i][Kaina] = kaina;
	Verslai[i][PelnasH] = pelnas;
	format(query,sizeof(query),"INSERT INTO `verslai` (EnX,EnY,EnZ,InterjeroNr,Kaina,PelnasH)VALUES(%f,%f,%f,%d,%d,%d)",
	pos[0],pos[1],pos[2],interjeras,kaina,pelnas); // formatuojame užklausą: įašyti duomenis į lentelę "verslai"
	mysql_tquery(Db,query,"OnPridejusVersla","i",i); // Išsiunčiame užklausą, ir jai gryžus nurodome iškviesti funkciją "OnPridejusVersla"
	format(str,sizeof(str),"Verslas parduodamas\nKaina:%d\nValandos pelnas:%d",Verslai[i][Kaina],Verslai[i][PelnasH]);
	Verslai[i][Label] = Create3DTextLabel(str,VERSLU_SPALVA,Verslai[i][EnX],Verslai[i][EnY],Verslai[i][EnZ],25,0,1);
	return 1;
}

forward OnPridejusVersla(index);
public OnPridejusVersla(index)
{
	Verslai[index][Id] = cache_insert_id(); // Ši funkcija gražina sekantį "Auto incremented" stulpelio skaičių.
	 
	//Atliekame tuos pačius veiksmus kaip kraunant, todėl jų nekomentuosiu.
	//Na gerai, tik pagrindinius dalykus
	Verslai[index][Ormid] = orm_create("verslai"); // Sukuriame ryšį su lentele "verslai"
	orm_addvar_int(Verslai[index][Ormid],Verslai[index][Id],"Id");
	orm_setkey(Verslai[index][Ormid],"Id"); // Nustatome kad eilutes skirsime pagal stulpelį "Id"
	orm_addvar_string(Verslai[index][Ormid],Verslai[index][Savininkas],MAX_PLAYER_NAME,"Savininkas");
	orm_addvar_string(Verslai[index][Ormid],Verslai[index][Pavadinimas],101,"Pavadinimas");
	orm_addvar_float(Verslai[index][Ormid],Verslai[index][EnX],"EnX");
	orm_addvar_float(Verslai[index][Ormid],Verslai[index][EnY],"EnY");
	orm_addvar_float(Verslai[index][Ormid],Verslai[index][EnZ],"EnZ");
	orm_addvar_int(Verslai[index][Ormid],Verslai[index][InterjeroNr],"InterjeroNr");
	orm_addvar_int(Verslai[index][Ormid],Verslai[index][Kaina],"Kaina");
	orm_addvar_int(Verslai[index][Ormid],Verslai[index][PelnasH],"PelnasH");
	orm_addvar_int(Verslai[index][Ormid],Verslai[index][Pelnas],"Pelnas");
	orm_addvar_int(Verslai[index][Ormid],Verslai[index][Locked],"Locked");
	return 1;
}

Ir paskutinė smulkmena be kurios būtų nuobodu(ir nepelninga) turėti verslą. Tai pelno augimas. Tai yra tik timeris kurį norėsite paleisti "OnGameModeInit" callback'e:

SetTimer("VersluPelnas",60*60*1000,true);

Ir "VersluPelnas" funkcija:

forward VersluPelnas();
public VersluPelnas()
{
	for(new i; i < MAX_VERSLAI; i++)
	{
		if(Verslai[i][Id] != 0) continue; 
		Verslai[i][Pelnas] += Verslai[i][PelnasH]; // Prideda pelną
		orm_update(Verslai[i][Ormid]); // Išsaugo viską į duomenų bazę
	}

Laiką galite keisti.

Ir viskas Yra daugybė dalykų kurių galima čia pridėti, pvz daugiau valdymo žaidime...

Kaip visada, komentuokit, vertinkit ir ieškokit klaidų!

Ech, vos nepamiršau, užklausą lentelei sukurti:

CREATE TABLE IF NOT EXISTS `verslai` (
`Id` int(11) NOT NULL AUTO_INCREMENT,
`Savininkas` varchar(24) NOT NULL,
`Pavadinimas` varchar(101) NOT NULL,
`EnX` float NOT NULL,
`EnY` float NOT NULL,
`EnZ` float NOT NULL,
`InterjeroNr` tinyint(4) NOT NULL,
`Kaina` int(11) NOT NULL,
`PelnasH` int(11) NOT NULL,
`Pelnas` int(11) NOT NULL,
`Locked` tinyint(4) NOT NULL,
PRIMARY KEY (`Id`)
) ENGINE=InnoDB DEFAULT CHARSET=latin1 AUTO_INCREMENT=1 ;

Patingėjau tai kelti į .sql failą.

Veikianti modifikacija su pamokos kodu:

Failai.LT

Pastebin

Padėkos:

Titas už surastą klaidą;

Slayer_ už surastą klaidą

Redaguota Kovo 13, 2014, nario Justas Š.

Slayer_ · Rugsėjo 24, 2013

Puiki pamoka, šaunuolis, jog sukūrei ją. Ateityje man jos tikrai prireiks. Ačiū.

Dovis_Sander · Rugsėjo 24, 2013

Žiauriai gera pamoka bei sistemą,daug kam pravers .

Ender · Rugsėjo 24, 2013

ACIU!!!!

mantasxx2 · Rugsėjo 29, 2013

Iš samp.com ištraukta mačiau šita pamoka

bebras · Rugsėjo 29, 2013

Iš samp.com ištraukta mačiau šita pamoka

Parodyk link iš samp.com.

Minion · Rugsėjo 29, 2013

Jaučiu nei vienas žmogus kuris perskaitė šią temą niekada nenaudos tokio būdo kurti verslų sistemą. Kodėl? Tikrai ne todėl, kad bloga pamoka, o todėl nes ČIA LIETUVA!

Lukass734 · Rugsėjo 29, 2013

TIkrai mldc.

arn0ldas · Spalio 1, 2013

Esu visiskai zalias sioje sritije ga kas galetu padeti mano skype arn00ldas 00 cia nuliai buciau labai dekingas

bebras · Spalio 1, 2013

Skype pagalba neužsiimu,rašyk čia.

bebras · Spalio 14, 2013

Atnaujinta. Funkcijoje "OnPridejusVersla" kurią iškviečia komanda "pridetiversla" naudojau "orm_apply_cache" kuris šiuo metu pakrautos duomenis išsaugo į kintamuosius. Bet kažkaip neatsižvelgiau kad prieš tai siunčiau "INSERT INTO" tipo užklausą ir užkrautų duomenų nėra.

*DeMo* · Spalio 15, 2013

+Rep prireiks kam nors

bebras · Gruodžio 24, 2013

Tema atnaujinta Ačiū Slayer_ už rastą klaidą

Kodo eilutės sunumeruotos.

Nike_Eisma · Gruodžio 24, 2013

Na smagu, panašia sistema ir aš naudoju.

Redaguota Rugpjūčio 29, 2015, nario Quality_Eisma

bryan · Gruodžio 24, 2013

Pamoka ? :lol: Gaila, bet ne. Laisvai galima pavadinti scripto gabalu.

bebras · Gruodžio 24, 2013

Pamoka ? Gaila, bet ne. Laisvai galima pavadinti scripto gabalu.

Paaiškinimai PO kodu.

bryan · Gruodžio 24, 2013

Paaiškinimai labai nesuprantami, bei nedabaigti.

wuPoR · Gruodžio 24, 2013

Paaiškinimai labai nesuprantami, bei nedabaigti.

Jei nenori suprast ir nesuprasi, jeigu nei kiek nesupranti, pirmą kartą atsidaręs pawn ir pradėjęs scriptinti, aiškink kaip nori iš kart tokių dalykų nesuprasi. Jei tau tai scripto gabalas, pats nematęs koki tikri "gabalai" yra, kai nieko neparašyta prieš kodą, nei po, tik įmesta pats kodas.

Redaguota Gruodžio 24, 2013, nario wuPoR

ignas612 · Gruodžio 25, 2013

Dėkui už pamoką labai pravertė ,tikrai nemokėjau

maperis9 · Kovo 12, 2014

http://www.gta-online.lt/v3/threads/pamoka-versl%C5%B3-sistema.18984/ ?

Prisijungti

[Pamoka]Verslų sistema

Recommended Posts

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Prisijungti prie diskusijos

Šiame puslapyje naršo: 0 nariai

Skelbimai

Naujausios temos

Naujausi būsenos atnaujinimai Nustatymai Teksto formatavimas Nario nuotrauka Member Išsaugoti

Nustatymai

Populiariausi nariai

Naujausi būsenos atnaujinimai

Nustatymai

Teksto formatavimas

Nario nuotrauka

Member