[Pamoka]MySQL saugojimas/krovimas

bebras · Rugsėjo 13, 2013

Sveiki, nusprendžiau parašyti pamoką apie MySQL saugojimą ir krovimą. Įprastas klausimas būtų: "kokios versijos?", atsakymas - R5,R7,R33. Taigi, apžvelgsiu visas tris, kadangi jos yra populiariausios ir veikia skirtingai.

Turinys:

Įvadas

R5

R7

R33

Informacija kuri bus naudojama visuose pavyzdžiuose:

//Susikuriame enum kad būtų lengviau sekti informaciją, nors galime naudoti ir DEFINE ar const.
enum Players {
ID,
Vardas[MAX_PLAYER_NAME],
Pinigai,
Xp,
Darbas,
Float:Hp
};
new pInfo[MAX_PLAYERS][Players]; // Sukuriame masyvą.

Kodas sukurti mūsų naudojamai lentelei(kodas turi būti naudojamas phpmyadmin -> SQL):

CREATE TABLE IF NOT EXISTS `zaidejai` (
`ID` int(11) NOT NULL AUTO_INCREMENT,
`Vardas` varchar(24) NOT NULL,
`Pinigai` int(11) NOT NULL,
`Xp` int(11) NOT NULL,
`Darbas` tinyint(11) NOT NULL,
`Hp` float(11) NOT NULL,
PRIMARY KEY (`ID`)
) ENGINE=InnoDB DEFAULT CHARSET=latin1 AUTO_INCREMENT=1 ;

Įvadas

Kodėl MySQL? Apie MySQL greitį net nekalbėsiu, nes lyginti net nėra ką. Ji taipat turi kalnus papildomų(naudingų) funkcijų, kaip "auto_increment" kas automatiškai suteikia nurodytam stulpeliui unikalų skaičių(mes tai naudosime stulpeliui "ID"), taipat tai yra "ryšinė" duomenų bazę, kam reikėtų atskiros temos(vis neprisiruošiu parašyti)... Bet trumpai, vienos eilutės gali priklausyti nuo kitų, t.y. ištrynus vieną, dings ir kitas....

R5

Ši versija yra pati lėčiausia, bet kažkodėl - populiariausia.... Kas mane labai liūdina... Visgi, pradėkim nuo krovimo:

stock LoadStats(playerid) // Susikursime funkciją kad krauti galėtumėme kada tik panorėjus
{
new name[MAX_PLAYER_NAME],query[70];
GetPlayerName(playerid,name,sizeof(name));
format(query,sizeof(query),"SELECT * FROM zaidejai WHERE Vardas = '%s'",name); // Pasirenkame viską iš lentelės "zaidejai" kur vardas yra lygus kintamajam "name"
mysql_query(query); // Išsiunčiame užklausą
mysql_store_result(); // Išsaugome rezultatą
if(mysql_retrieve_row()) // Šita funkcija perkelia vidinį "skirtuką" į sekančią eilutę, jeigu nėra daugiau eilučių, gražina 0.  
{
new tmp[32];
// Mysql_fetch_field_row funkcija kaip parametrą priema tik "string" tipo kintamuosius, todėl sukūrėme kintamąjį "tmp"
// Pakeisti iš "string" tipo į "integer" naudosime "strval" funkciją "strval"
// Pakeisti iš "string" tipo į "float" tipą naudosime funkciją "floatstr"
mysql_fetch_field_row(tmp,"ID"); pInfo[playerid][ID] = strval(tmp);
mysql_fetch_field_row(pInfo[playerid][Vardas],"Vardas");
mysql_fetch_field_row(tmp,"Pinigai"); pInfo[playerid][Pinigai]= strval(tmp);
mysql_fetch_field_row(tmp,"Xp"); pInfo[playerid][Xp] = strval(tmp);
mysql_fetch_field_row(tmp,"Darbas"); pInfo[playerid][Darbas] = strval(tmp);
mysql_fetch_field_row(tmp,"Hp"); pInfo[playerid][Hp] = floatstr(tmp);
}
mysql_free_result(); // "Išlaisviname" gautą rezultą iš atminties
return 1;
}

Krovimas yra, galima ir išsaugoti duomenis....

stock SaveStats(playerid) // Susikursime funkciją kad krauti galėtumėme kada tik panorėjus
{
new query[100];
//Suformatuojame užklausą kuri "atnaujins" lentelę "zaidejai" kur stulpelis "ID" lygus kintamajama "pInfo[playerid][ID]"
format(query,sizeof(query),"UPDATE zaidejai SET Pinigai = %d, Xp = %d, Darbas = %d, Hp = %f WHERE ID = %d",
pInfo[playerid][Pinigai],pInfo[playerid][Xp],pInfo[playerid][Darbas],pInfo[playerid][Hp],pInfo[playerid][ID]);
mysql_query(query);
return 1;
}

Krovimas tėra 4 eilutės kodo... Paprasčiau nebūna! Su R6 tiek, gavimo ir išsiuntimo užklausų šablonas yra, galite nesunkiai papildyti ar perdaryti jas.

R7

Ši versija yra viena iš greitesnių. Greičio testas lyginant su R5 Esminiai R7 skirtumai tai kad šios užklausos yra vykdomos atskirame "thread", ką tai reiškia? Tai reiškia kad serveris neturi laukti kol užklausa baigs darbą kad galėtų tęsti. Kita naujiena (lyginant su R6) yra kad užklausa grįždama su informacija iškviečia kitą (jūsų nurodyta) funkciją(R32 veikia su y_inline)...
Iš šių žodžių tai atrodo labai sudėtinga ir atbaido daugumą žmonių nuo šios versijos, bet kai pamatysite kodą, viskas pasidarys paprasta kaip 2 + 2 (lygu 5)... Lekiame prie krovimo:

stock LoadStats(playerid) // Susikursime funkciją kad krauti galėtumėme kada tik panorėjus
{
new name[MAX_PLAYER_NAME],query[70];
GetPlayerName(playerid,name,sizeof(name));
mysql_real_escape_string(name,name);
format(query,sizeof(query),"SELECT * FROM zaidejai WHERE Vardas = '%s'",name); // Pasirenkame viską iš lentelės "zaidejai" kur vardas yra lygus kintamajam "name"
// Kolkas viskas buvo kaip senoje versijoje, dabar prasideda naujovės:
mysql_function_query(connection_handler,query,true,"OnPlayerInfoLoad","i",playerid); // Pakomentuosiu žemiau
return 1;
}
// Funkciją kuria nurodėme aukščiau, ji PRIVALO būti public (kas reiškia turi būti ir forward)
forward OnPlayerInfoLoad(playerid);
public OnPlayerInfoLoad(playerid)
{
new rows,fields;
cache_get_data(rows,fields); // Išgauname informaciją apie eilučių ir laukų skaičių ir įrašome juos į kintamuosius "rows,fields"
if(rows == 1) // Jeigu yra viena eilutė
{
new tmp[32];
// cache_get_row funkcija kaip parametrą priema tik "string" tipo kintamuosius, todėl sukūrėme kintamąjį "tmp"
// Pakeisti iš "string" tipo į "integer" naudosime "strval" funkciją "strval"
// Pakeisti iš "string" tipo į "float" tipą naudosime funkciją "floatstr"
cache_get_row(0,0,tmp); pInfo[playerid][ID] = strval(tmp);
cache_get_row(0,1,pInfo[playerid][Vardas]);
cache_get_row(0,2,tmp); pInfo[playerid][Pinigai]= strval(tmp);
cache_get_row(0,3,tmp); PInfo[playerid][Xp] = strval(tmp);
cache_get_row(0,4,tmp); pInfo[playerid][Darbas] = strval(tmp);
cache_get_row(0,5,tmp); pInfo[playerid][Hp] = floatstr(tmp);
}
return 1; // Būtina, kitaip funkcija bus kviečiama ir kviečiama...
}

Kodas gal šiektiek ir pailgėjo...
Dabar dėl šios eilutės: "mysql_function_query(connection_handler,query,true,"OnPlayerInfoLoad","i",playerid);"
"connection_handler" - tai yra duomenų bazės id kuriuo bus siunčiama užklausą, jį galima išgauti iš "mysql_connect" funkcijos, pvz:

new Duombaze;
public OnGameModeInit()
{
Duombaze = mysql_connect(ip,vartotojas,duombaze,slaptazodis);
}

Tokiu atveju vietoj "connection_handler" rašytume "Duombaze"

query - nurodome kad siunčiame tai kas yra kintamajame "query"
true - šis parametras rodo ar naudosime "cache" funkciją.. Ja naudosime gaunant informaciją. (Vėlesnėse versijose parametras panaikintas)
"OnPlayerInfoLoad" - nurodome funkcijos pavadinimą, kurią turės iškviesti užklausa kai "grįš" iš duomenų bazės
"i" - nurodome kad pridėsime papildomą parametrą "int" tipo
playerid - tai ir yra papildomas parametras

Keliaujame prie saugojimo:

stock SaveStats(playerid)
{
new query[100];
//Suformatuojame užklausą kuri "atnaujins" lentelę "zaidejai" kur stulpelis "ID" lygus kintamajama "pInfo[playerid][ID]"
format(query,sizeof(query),"UPDATE zaidejai SET Pinigai = %d, Xp = %d, Darbas = %d, Hp = %f WHERE ID = %d",
pInfo[playerid][Pinigai],pInfo[playerid][Xp],pInfo[playerid][Darbas],pInfo[playerid][Hp],pInfo[playerid][ID]);
mysql_function_query(connection_handler,query,false,"","",); // Jokių funkcijų iškviesti nereikia nes informaciją siunčiame Į duombazę
return 1;
}

Saugojimas ir vėl labai trumpas....

R33

O dabar - perversmas. Naujoji funkcija yra dar greitesnė, greičio testas lyginant su R7. Čia, skirtumų nevardinsiu kadangi jų nemažai...
Su R33, pirmiausia reikia sukurti ryšį su lentele, ir tik paskui kurti "krovimą" ar ką kitą... Tai ir padarykime:

new ORM:ORMID[MAX_PLAYERS]; // Reikės papildomo kintamojo kad išsaugotume ryšį tarp žaidėjo ir lentelės
public OnPlayerConnect(playerid)
{
GetPlayerName(playerid,pInfo[playerid][Vardas],24);

ORMID[playerid] = orm_create("zaidejai"); //Sukuriame ryšį tarp kintamojo "ORMID[playerid]" ir lentelės "zaidejai"

//Dabar nurodysime su kokiais duomenimis dirbsime
orm_addvar_int(ORMID[playerid],pInfo[playerid][ID],"ID"); // Pridedame "integer" tipo kintamajį
orm_addvar_string(ORMID[playerid],pInfo[playerid][Vardas],24,"Vardas"); //Pridedame "string" tipo kintamąjį
orm_addvar_int(ORMID[playerid],pInfo[playerid][Pinigai],"Pinigai");
orm_addvar_int(ORMID[playerid],pInfo[playerid][Xp],"Xp");
orm_addvar_int(ORMID[playerid],pInfo[playerid][Darbas],"Darbas");
orm_addvar_float(ORMID[playerid],pInfo[playerid][Hp],"Hp"); // Pridedame "float" tipo kintamajį

orm_setkey(ORMID[playerid],"Vardas"); // Nurodysime jog skirsime eilutes nuo kitų pagal stulpelį "Vardas"
return 1;
}
//Šiuo metu jokio krovimo ar saugojimo nebus, sukūrėme tik ryšį.




stock LoadStats(playerid)
{
orm_select(ORMID[playerid],"OnPlayerInfoLoad","i",playerid); // Nurodome kad būtų išsiųsta "select"(parenkamojo) tipo užklausa.
//"OnPlayerInfoLoad" nurodome kokią funkciją iškviesti kai užklausa "grįš" su duomenimis
//"i" nurodome kad pridėsime papildomą "integer" tipo parametrą
// playerid tai ir yra papildomas parametras
return 1;
}
forward OnPlayerInfoLoad(playerid);
public OnPlayerInfoLoad(playerid)
{
if(orm_errno(ORMID[playerid]) == ERROR_OK)
// funkcija "orm_errno" praneša kaip "sekėsi" užklausai ir turi dvi galimybes: "ERROR_OK" kas reiškia kad viskas buvo gerai, ir "ERROR_NO_DATA" kas reiškia jog nebuvo duomenų
{
//Duomenys jau užkrauti, mums nebėra ką daryti
}
return 1;
}

Krovimas atrodo sudėtingas, bet jame yra ir visa saugojimo esmė....Prie jo ir pereikime:

stock SaveStats(playerid)
{
orm_update(ORMID[playerid]);
return 1;
}

Viskas, tos 2 eilutės atnaujins visus duomenis!!

Štai ir pabaiga. Asmeniškai ,rekomenduočiau R33... Ką naudoti - rinktis jums.

Jeigu turite klausimų, pasiūlymų ar nuomonę, mielai išklausysiu! Gero vakaro!

Redaguota Sausio 17, 2014, nario Justas Š.

laimis321 · Rugsėjo 13, 2013

Pravers +rep

Tomas · Rugsėjo 13, 2013

Šaunu

R4imis · Rugsėjo 14, 2013

Sveikas, man kažkodėl nesaugoja..

Štai kodas:

stock UzkraunamZaideja(playerid)
{
new name[MAX_PLAYER_NAME],query[70];
GetPlayerName(playerid,name,sizeof(name));
format(query,sizeof(query),"SELECT * FROM vartotojai WHERE Vardas = '%s'",name); // Pasirenkame viską iš lentelės "zaidejai" kur vardas yra lygus kintamajam "name"
mysql_query(query);
mysql_store_result();
if(mysql_num_rows() == 1)
{
 new tmp[32];
 mysql_fetch_field_row(tmp,"Darbas"); Zaidejas[playerid][Darbas] = strval(tmp);
}
mysql_free_result();
return 1;
}

stock IssaugomZaideja(playerid)
{
new query[100], name[MAX_PLAYER_NAME];
GetPlayerName(playerid, name, sizeof(name));
format(query,100,"UPDATE vartotojai SET Darbas = %i WHERE Vardas = '%s'", Zaidejas[playerid][Darbas]);
mysql_query(query);
return 1;
}

P.S. Naudoju R5 pluginą

Scriptingas · Rugsėjo 14, 2013

stock IssaugomZaideja(playerid)
{
new query[100], name[MAX_PLAYER_NAME];
GetPlayerName(playerid, name, sizeof(name));

format(query,100,"UPDATE `vartotojai` SET `Darbas` = '%i' WHERE Vardas = '%s'", Zaidejas[playerid][Darbas], name);
mysql_query(query);
return 1;
}

R4imis · Rugsėjo 14, 2013

stock IssaugomZaideja(playerid)
{
new query[100], name[MAX_PLAYER_NAME];
GetPlayerName(playerid, name, sizeof(name));

format(query,100,"UPDATE `vartotojai` SET `Darbas` = '%i' WHERE Vardas = '%s'", Zaidejas[playerid][Darbas], name);
mysql_query(query);
return 1;
}

VIstiek nesaugoja, nesuprantu jau kiek laiko knisuos prie saugojimo ir niekaip neina..

bebras · Rugsėjo 14, 2013

Parodyk mysql log

R4imis · Rugsėjo 14, 2013

Parodyk mysql log

MySQL logas:

[15:22:51]

[15:22:51] ---------------------------

[15:22:51] MySQL Debugging activated (09/14/13)

[15:22:51] ---------------------------

[15:22:51]

[15:22:51] >> mysql_connect( )

[15:22:51] CMySQLHandler::CMySQLHandler() - constructor called.

[15:22:51] CMySQLHandler::CMySQLHandler() - Connecting to "localhost" | DB: "Mokinuos" | Username: "root" ...

[15:22:51] CMySQLHandler::Connect() - Connection was successful.

[15:22:51] CMySQLHandler::Connect() - Auto-Reconnect has been enabled.

[15:22:51] >> mysql_ping( Connection handle: 1 )

[15:22:51] CMySQLHandler::Ping() - Connection is still alive.

[15:23:19] >> mysql_query( Connection handle: 1 )

[15:23:19] CMySQLHandler::Query(SELECT * FROM `vartotojai` WHERE `Vardas` = 'black') - Successfully executed.

[15:23:19] >> mysql_store_result( Connection handle: 1 )

[15:23:19] CMySQLHandler::StoreResult() - Result was stored.

[15:23:19] >> mysql_num_rows( Connection handle: 1 )

[15:23:19] CMySQLHandler::NumRows() - Returned 0 row(s)

[15:23:19] >> mysql_free_result( Connection handle: 1 )

[15:23:19] CMySQLHandler::FreeResult() - Result was successfully free'd.

[15:23:23] >> mysql_query( Connection handle: 1 )

[15:23:23] CMySQLHandler::Query(INSERT INTO `vartotojai` (Vardas,Slaptazodis) VALUES ('black','a')) - Successfully executed.

[15:23:25] >> mysql_query( Connection handle: 1 )

[15:23:25] CMySQLHandler::Query(UPDATE `vartotojai` SET `Darbas` = 0 WHERE Vardas = '') - Successfully executed.

bebras · Rugsėjo 14, 2013

prieš formatuojant užklausą, pridėk "printf("%s",name);"...

Kaip suprantu iš log, kintamasis "name" yra tuščias :/ Neperdarei funkcijos "GetPlayerName"?

R4imis · Rugsėjo 14, 2013

prieš formatuojant užklausą, pridėk "printf("%s",name);"...

Kaip suprantu iš log, kintamasis "name" yra tuščias :/ Neperdarei funkcijos "GetPlayerName"?

VIskas veikia GetPlayerName funkcija esu padares. Uzsaugojimas veikia, tačiau nekrauna kas gali būti blogai?

MySQL logas:

Čia turbūt kažkas netaip

[00:19:08] CMySQLHandler::FetchField(Darbas) - You cannot call this function now. (Reason: Fields/Rows are empty.)

bebras · Rugsėjo 15, 2013

Tai reiskia kad nera duomenu. Parodyk krovima

R4imis · Rugsėjo 15, 2013

Tai reiskia kad nera duomenu. Parodyk krovima

Krovimo kodas:

stock UzkraunamZaideja(playerid)
{
new name[MAX_PLAYER_NAME],query[1300];
GetPlayerName(playerid,name,sizeof(name));
format(query,1300,"SELECT * FROM `vartotojai` WHERE Vardas = '%s'",name); // Pasirenkame viską iš lentelės "zaidejai" kur vardas yra lygus kintamajam "name"
mysql_query(query);
mysql_store_result();

new tmp[1300];
mysql_fetch_field_row(tmp,"Darbas"); Zaidejas[playerid][Darbas] = strval(tmp); Zaidejas[playerid][Darbas] = Zaidejas[playerid][Darbas];
mysql_fetch_field_row(tmp, "Pinigai"); Zaidejas[playerid][Pinigai] = strval(tmp); GivePlayerMoney(playerid, Zaidejas[playerid][Pinigai]);
mysql_free_result();
return 1;
}

bebras · Rugsėjo 15, 2013

Masyvų dydis 1300.....

"Zaidejas[playerid][Darbas] = Zaidejas[playerid][Darbas];" WAT?

Tau pagrindus reiktų mokintis...

Pridėk po store_result:

printf("Eilutės:%d",mysql_num_rows());

Ir pasakyk ką išprintins

R4imis · Rugsėjo 16, 2013

Masyvų dydis 1300.....

"Zaidejas[playerid][Darbas]=Zaidejas[playerid][Darbas];" WAT?

Tau pagrindus reiktų mokintis...

Pridėk po store_result:
printf("Eilutės:%d",mysql_num_rows());
Ir pasakyk ką išprintins

Jau viskas veikia dėkui tau už pagalbą

bebras · Sausio 17, 2014

Pataisytas R5 krovimas dėl kurio galėjo atsirasti tokių klaidų mysql log'e

 You cannot call this function now. (Reason: Fields/Rows are empty.)

SaSkript · Sausio 17, 2014

R5 LoadStats:

mysql_fetch_field_row(tmp,"Xp"); PInfo[playerid][Xp] = strval(tmp);

Jokios klaidos nėra?

Redaguota Sausio 17, 2014, nario SaSkript

bebras · Sausio 17, 2014

R5 LoadStats:
mysql_fetch_field_row(tmp,"Xp"); PInfo[playerid][Xp] = strval(tmp);
Jokios klaidos nėra?

Taip, yra. "pInfo" parašytas iš didžiosios raidės.

Pataisyta, ačiū už pastabą

Bicas_Biciuks · Vasario 1, 2014

Justai, gal galėtum man plačiau apie r33/34? Nesusigaudau aš ten skype robis.ltu. kai turėsi laisvo laiko pakviesk.

MaxSis · Vasario 1, 2014

nusipirk valgyti už repus

wuPoR · Vasario 2, 2014

nusipirk valgyti už repus

Pff, čia tiek repu jam, aš modą paplatinęs dvigubai daugiau gavau xd

Prisijungti

[Pamoka]MySQL saugojimas/krovimas

Recommended Posts

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Nuoroda į komentarą

Dalintis per kitą puslapį

Prisijungti prie diskusijos

Šiame puslapyje naršo: 0 nariai

Skelbimai

Naujausios temos

Naujausi būsenos atnaujinimai Nustatymai Teksto formatavimas Nario nuotrauka Member Išsaugoti

Nustatymai

Populiariausi nariai

Naujausi būsenos atnaujinimai

Nustatymai

Teksto formatavimas

Nario nuotrauka

Member